island-story/src/player.s

INCLUDE "hardware.inc"
INCLUDE "input.inc"
INCLUDE "oam.inc"
INCLUDE "util.inc"

Section "Player Data", WRAM0

playerWorldX: dw
playerWorldY: dw

; player data
PLAYER_X:: db
PLAYER_Y:: dw
PLAYER_DIR:: db

PLAYER_JUMPING:: db
PLAYER_VY:: dw

Section "Player Code", ROM0

spriteData:
    INCBIN "png/sprite/player.2bpp"

DEF SPRITE_OAM_IDX EQU 0
DEF SPRITE_IDX EQU 32 ; tile index, rename later
DEF SPRITE_WIDTH EQU 2
DEF SPRITE_HEIGHT EQU 2
DEF PLAYER_SPEED EQU 2

DEF GRAVITY EQU (0 << 8) | $2e ; 0.18
DEF INIT_VY EQU (3 << 8) | $99 ; 3.60
DEF INIT_FALL_VY EQU ($ff << 8) | $1a ; a.b

Player_Init::
    ; Clear player data
    ld hl, PLAYER_X
    ld [hl], 0
    inc hl
    ld [hl], 144-32
    inc hl
    ld [hl], 0
    inc hl
    ld [hl], 0
    inc hl
    ld [hl], 0
    inc hl
    ld [hl], 0
    inc hl
    ld [hl], 0

    ; Copy sprite to VRAM
    ld bc, _VRAM8000 + SPRITE_IDX * 16
    ld hl, spriteData
    ld d, 16 * (SPRITE_WIDTH * SPRITE_HEIGHT)
    call memcpy

    ; Initialize OAM entries with player state
    call update_oam

    ret

Player_Update::
    ld hl, keys
    ld b, [hl]

    ; check for jump
    ld a, b
    and BTN_UP
    jr z, .jump_update_check

    ; initialize jump state if not already jumping
    ld hl, PLAYER_JUMPING
    ld a, [hl]
    or a
    jr nz, .jump_update

    ld [hl], 1

    ld hl, PLAYER_VY
    STORE16 INIT_VY

; todo: deduplicate
.jump_update_check:
    ld hl, PLAYER_JUMPING
    ld a, [hl]
    or a
    jr z, .right

.jump_update:
    ; load y velocity into bc
    ld hl, PLAYER_VY
    ld b, [hl]
    inc hl
    ld c, [hl]

    ; adjust velocity by gravity
    ld a, c
    sub LOW(GRAVITY)
    ld c, a
    ld a, b
    sbc HIGH(GRAVITY)
    ld b, a

    ld hl, PLAYER_VY
    STORE16 bc

    ; y -= floor(vy)
    ld hl, PLAYER_Y + 1
    ld a, [hl]
    sub c
    ld [hl-], a
    ld a, [hl]
    sbc b
    ld [hl], a

    ; roll back jump if there was a collision
    call player_bg_collides
    jr z, .jump_update_oam

.jump_rollback:
    ld hl, PLAYER_VY
    bit 7, [hl]

    ld hl, PLAYER_Y
    jr z, .jump_rollback_down
    dec [hl]
    jr .jump_rollback_check

.jump_rollback_down:
    inc [hl]

.jump_rollback_check:
    call player_bg_collides
    jr nz, .jump_rollback

    ; set PLAYER_JUMPING = 0 if VY < 0 (fell into ground)
    ld hl, PLAYER_VY
    bit 7, [hl]

    ; either way, set VY = 0
    ld [hl], 0
    ld hl, PLAYER_VY + 1
    ld [hl], 0

    jr z, .jump_update_oam

    ld hl, PLAYER_JUMPING
    ld [hl], 0

.jump_update_oam:
    call update_oam

    ; check for move right
.right:
    ld hl, keys
    ld a, [hl]
    and BTN_RIGHT
    jr z, .left

    ; check for right boundary
    ld hl, PLAYER_X
    ld a, [hl]
    add 16
    cp SCRN_X
    jr nc, .left

    inc [hl]
    inc [hl]

    call player_bg_collides
    jr nz, .right_rollback

    ld hl, PLAYER_DIR
    ld [hl], 0

    call update_oam
    ret

.right_rollback:
    ld hl, PLAYER_X
    dec [hl]
    dec [hl]
    ret

.left:
    ; check for left button
    ld hl, keys
    ld a, [hl]
    and BTN_LEFT
    jr z, .fall

    ; check for left boundary
    ld hl, PLAYER_X
    ld a, [hl]
    or a
    jr z, .fall

    sub PLAYER_SPEED
    ld [hl], a

    call player_bg_collides
    jr nz, .left_rollback

    ld hl, PLAYER_DIR
    ld [hl], $ff

    call update_oam
    jr .fall

.left_rollback:
    ld hl, PLAYER_X
    inc [hl]
    inc [hl]

.fall:
    call player_in_air
    ret nz

    ; only set jump state if not already jumping
    ld hl, PLAYER_JUMPING
    ld a, [hl]
    or a
    ret nz

    ld [hl], 1

    ld hl, PLAYER_VY
    STORE16 INIT_FALL_VY

    ret

; Update player metasprite with positional data
update_oam:
    ld hl, PLAYER_DIR
    ld a, [hl-] ; dir (0 = right , $ff = left)
    and OAMF_XFLIP
    ld c, a

    dec hl ; skip fractional part
    ld a, [hl-] ; y
    add 16

    ld d, a
    ld a, [hl] ; x
    add 8
    ld b, a
    ld a, d

    ld_OAM_y hl, SPRITE_OAM_IDX

    ; top left sprite
    ld [hli], a
    ld [hl], b
    inc hl
    ld [hl], SPRITE_IDX
    inc hl
    ld [hl], c
    inc hl

    ; top right
    ld d, a
    ld a, b
    add 8
    ld b, a
    ld a, d

    ld [hli], a
    ld [hl], b
    inc hl
    ld [hl], SPRITE_IDX + 1
    inc hl
    ld [hl], c
    inc hl

    ; bottom left
    add 8
    ld d, a
    ld a, b
    sub 8
    ld b, a
    ld a, d

    ld [hli], a
    ld [hl], b
    inc hl
    ld [hl], SPRITE_IDX + 2
    inc hl
    ld [hl], c
    inc hl

    ; bottom right
    ld d, a
    ld a, b
    add 8
    ld b, a
    ld a, d

    ld [hli], a
    ld [hl], b
    inc hl
    ld [hl], SPRITE_IDX + 3
    inc hl
    ld [hl], c

    ; flip tile indices if necessary
    ld a, c
    or c
    jr z, .done

    ld_OAM_tile hl, SPRITE_OAM_IDX
    ld [hl], SPRITE_IDX + 1

    ld_OAM_tile hl, SPRITE_OAM_IDX + 1
    ld [hl], SPRITE_IDX

    ld_OAM_tile hl, SPRITE_OAM_IDX + 2
    ld [hl], SPRITE_IDX + 3

    ld_OAM_tile hl, SPRITE_OAM_IDX + 3
    ld [hl], SPRITE_IDX + 2

.done:
    ret